# Maintainer: Mineralwater Xu <mineralwater@m1neralwater.com>

pkgbase=qbittorrent-mw
pkgname=('qbittorrent-mw' 'qbittorrent-mw-nox')
pkgver=4.4.1
pkgrel=1
arch=('x86_64')
url='https://www.qbittorrent.org'
license=('custom' 'GPL')
depends=('libtorrent-rasterbar-mw' 'qt6-base')
makedepends=('cmake' 'boost' 'qt6-tools' 'qt6-svg')
optdepends=('python: needed for torrent search tab')
provides=('qbittorrent')
conflicts=('qbittorrent')
source=("https://downloads.sourceforge.net/sourceforge/qbittorrent/qbittorrent-${pkgver}.tar.xz"{,.asc})
sha512sums=('9ced98091c972c682114cf9fa973a57086a8914081ffe6ed90c08136de2b48049b3a69669c43923b261389dbe84ac988c216180b662cf5e51715981b58826c0d'
            'SKIP')
validpgpkeys=('D8F3DA77AAC6741053599C136E4A2D025B7CC9A2') # sledgehammer999 <sledgehammer999@qbittorrent.org>

prepare() {
  cd qbittorrent-${pkgver}
}

build() {
  cmake -B build -S qbittorrent-$pkgver \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DQT6=ON
  cmake --build build

  cmake -B build-nox -S qbittorrent-$pkgver \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DQT6=ON \
    -DGUI=OFF \
    -DSYSTEMD=ON
  cmake --build build-nox
}

package_qbittorrent-mw() {
  pkgdesc="An advanced BitTorrent client programmed in C++, based on Qt toolkit and libtorrent-rasterbar."
  depends+=('qt6-svg' 'hicolor-icon-theme')
  provides=('qbittorrent')
  conflicts=('qbittorrent')

  DESTDIR="${pkgdir}" cmake --install build
  install -Dm644 qbittorrent-${pkgver}/COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
}

package_qbittorrent-mw-nox() {
  pkgdesc="An advanced BitTorrent client programmed in C++, based on Qt toolkit and libtorrent-rasterbar, w/o gui"
  provides=('qbittorrent-nox')
  conflicts=('qbittorrent-nox')

  DESTDIR="${pkgdir}" cmake --install build-nox
  install -Dm644 qbittorrent-${pkgver}/COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
}